Linux v6.18.37 · 원본 파일 · 온라인 원본
1/*
2 * Helper macros to support writing architecture specific
3 * linker scripts.
4 *
5 * A minimal linker scripts has following content:
6 * [This is a sample, architectures may have special requirements]
7 *
8 * OUTPUT_FORMAT(...)
9 * OUTPUT_ARCH(...)
10 * ENTRY(...)
11 * SECTIONS
12 * {
13 * . = START;
14 * __init_begin = .;
15 * HEAD_TEXT_SECTION
16 * INIT_TEXT_SECTION(PAGE_SIZE)
17 * INIT_DATA_SECTION(...)
18 * PERCPU_SECTION(CACHELINE_SIZE)
19 * __init_end = .;
20 *
21 * _stext = .;
22 * TEXT_SECTION = 0
23 * _etext = .;
24 *
25 * _sdata = .;
26 * RO_DATA(PAGE_SIZE)
27 * RW_DATA(...)
28 * _edata = .;
29 *
30 * EXCEPTION_TABLE(...)
31 *
32 * BSS_SECTION(0, 0, 0)
33 * _end = .;
34 *
35 * STABS_DEBUG
36 * DWARF_DEBUG
37 * ELF_DETAILS
38 *
39 * DISCARDS // must be the last
40 * }
41 *
42 * [__init_begin, __init_end] is the init section that may be freed after init
43 * // __init_begin and __init_end should be page aligned, so that we can
44 * // free the whole .init memory
45 * [_stext, _etext] is the text section
46 * [_sdata, _edata] is the data section
47 *
48 * Some of the included output section have their own set of constants.
49 * Examples are: [__initramfs_start, __initramfs_end] for initramfs and
50 * [__nosave_begin, __nosave_end] for the nosave data
51 */
52
53#include <asm-generic/codetag.lds.h>
54
55#ifndef LOAD_OFFSET
56#define LOAD_OFFSET 0
57#endif
58
59/*
60 * Only some architectures want to have the .notes segment visible in
61 * a separate PT_NOTE ELF Program Header. When this happens, it needs
62 * to be visible in both the kernel text's PT_LOAD and the PT_NOTE
63 * Program Headers. In this case, though, the PT_LOAD needs to be made
64 * the default again so that all the following sections don't also end
65 * up in the PT_NOTE Program Header.
66 */
67#ifdef EMITS_PT_NOTE
68#define NOTES_HEADERS :text :note
69#define NOTES_HEADERS_RESTORE __restore_ph : { *(.__restore_ph) } :text
70#else
71#define NOTES_HEADERS
72#define NOTES_HEADERS_RESTORE
73#endif
74
75/*
76 * Some architectures have non-executable read-only exception tables.
77 * They can be added to the RO_DATA segment by specifying their desired
78 * alignment.
79 */
80#ifdef RO_EXCEPTION_TABLE_ALIGN
81#define RO_EXCEPTION_TABLE EXCEPTION_TABLE(RO_EXCEPTION_TABLE_ALIGN)
82#else
83#define RO_EXCEPTION_TABLE
84#endif
85
86/* Align . function alignment. */
87#define ALIGN_FUNCTION() . = ALIGN(CONFIG_FUNCTION_ALIGNMENT)
88
89/*
90 * LD_DEAD_CODE_DATA_ELIMINATION option enables -fdata-sections, which
91 * generates .data.identifier sections, which need to be pulled in with
92 * .data. We don't want to pull in .data..other sections, which Linux
93 * has defined. Same for text and bss.
94 *
95 * With LTO_CLANG, the linker also splits sections by default, so we need
96 * these macros to combine the sections during the final link.
97 *
98 * With AUTOFDO_CLANG and PROPELLER_CLANG, by default, the linker splits
99 * text sections and regroups functions into subsections.
100 *
101 * RODATA_MAIN is not used because existing code already defines .rodata.x
102 * sections to be brought in with rodata.
103 */
104#if defined(CONFIG_LD_DEAD_CODE_DATA_ELIMINATION) || defined(CONFIG_LTO_CLANG) || \
105defined(CONFIG_AUTOFDO_CLANG) || defined(CONFIG_PROPELLER_CLANG)
106#define TEXT_MAIN .text .text.[0-9a-zA-Z_]*
107#else
108#define TEXT_MAIN .text
109#endif
110#if defined(CONFIG_LD_DEAD_CODE_DATA_ELIMINATION) || defined(CONFIG_LTO_CLANG)
111#define DATA_MAIN .data .data.[0-9a-zA-Z_]* .data.rel.* .data..L* .data..compoundliteral* .data.$__unnamed_* .data.$L*
112#define SDATA_MAIN .sdata .sdata.[0-9a-zA-Z_]*
113#define RODATA_MAIN .rodata .rodata.[0-9a-zA-Z_]* .rodata..L*
114#define BSS_MAIN .bss .bss.[0-9a-zA-Z_]* .bss..L* .bss..compoundliteral*
115#define SBSS_MAIN .sbss .sbss.[0-9a-zA-Z_]*
116#else
117#define DATA_MAIN .data .data.rel .data.rel.local
118#define SDATA_MAIN .sdata
119#define RODATA_MAIN .rodata
120#define BSS_MAIN .bss
121#define SBSS_MAIN .sbss
122#endif
123
124/*
125 * GCC 4.5 and later have a 32 bytes section alignment for structures.
126 * Except GCC 4.9, that feels the need to align on 64 bytes.
127 */
128#define STRUCT_ALIGNMENT 32
129#define STRUCT_ALIGN() . = ALIGN(STRUCT_ALIGNMENT)
130
131/*
132 * The order of the sched class addresses are important, as they are
133 * used to determine the order of the priority of each sched class in
134 * relation to each other.
135 */
136#define SCHED_DATA \
137 STRUCT_ALIGN(); \
138 __sched_class_highest = .; \
139 *(__stop_sched_class) \
140 *(__dl_sched_class) \
141 *(__rt_sched_class) \
142 *(__fair_sched_class) \
143 *(__ext_sched_class) \
144 *(__idle_sched_class) \
145 __sched_class_lowest = .;
146
147/* The actual configuration determine if the init/exit sections
148 * are handled as text/data or they can be discarded (which
149 * often happens at runtime)
150 */
151
152#ifndef CONFIG_HAVE_DYNAMIC_FTRACE_NO_PATCHABLE
153#define KEEP_PATCHABLE KEEP(*(__patchable_function_entries))
154#define PATCHABLE_DISCARDS
155#else
156#define KEEP_PATCHABLE
157#define PATCHABLE_DISCARDS *(__patchable_function_entries)
158#endif
159
160#ifndef CONFIG_ARCH_SUPPORTS_CFI
161/*
162 * Simply points to ftrace_stub, but with the proper protocol.
163 * Defined by the linker script in linux/vmlinux.lds.h
164 */
165#define FTRACE_STUB_HACK ftrace_stub_graph = ftrace_stub;
166#else
167#define FTRACE_STUB_HACK
168#endif
169
170#ifdef CONFIG_DYNAMIC_FTRACE
171/*
172 * The ftrace call sites are logged to a section whose name depends on the
173 * compiler option used. A given kernel image will only use one, AKA
174 * FTRACE_CALLSITE_SECTION. We capture all of them here to avoid header
175 * dependencies for FTRACE_CALLSITE_SECTION's definition.
176 *
177 * ftrace_ops_list_func will be defined as arch_ftrace_ops_list_func
178 * as some archs will have a different prototype for that function
179 * but ftrace_ops_list_func() will have a single prototype.
180 */
181#define MCOUNT_REC() . = ALIGN(8); \
182 __start_mcount_loc = .; \
183 KEEP(*(__mcount_loc)) \
184 KEEP_PATCHABLE \
185 __stop_mcount_loc = .; \
186 FTRACE_STUB_HACK \
187 ftrace_ops_list_func = arch_ftrace_ops_list_func;
188#else
189# ifdef CONFIG_FUNCTION_TRACER
190# define MCOUNT_REC() FTRACE_STUB_HACK \
191 ftrace_ops_list_func = arch_ftrace_ops_list_func;
192# else
193# define MCOUNT_REC()
194# endif
195#endif
196
197#define BOUNDED_SECTION_PRE_LABEL(_sec_, _label_, _BEGIN_, _END_) \
198 _BEGIN_##_label_ = .; \
199 KEEP(*(_sec_)) \
200 _END_##_label_ = .;
201
202#define BOUNDED_SECTION_POST_LABEL(_sec_, _label_, _BEGIN_, _END_) \
203 _label_##_BEGIN_ = .; \
204 KEEP(*(_sec_)) \
205 _label_##_END_ = .;
206
207#define BOUNDED_SECTION_BY(_sec_, _label_) \
208 BOUNDED_SECTION_PRE_LABEL(_sec_, _label_, __start, __stop)
209
210#define BOUNDED_SECTION(_sec) BOUNDED_SECTION_BY(_sec, _sec)
211
212#define HEADERED_SECTION_PRE_LABEL(_sec_, _label_, _BEGIN_, _END_, _HDR_) \
213 _HDR_##_label_ = .; \
214 KEEP(*(.gnu.linkonce.##_sec_)) \
215 BOUNDED_SECTION_PRE_LABEL(_sec_, _label_, _BEGIN_, _END_)
216
217#define HEADERED_SECTION_POST_LABEL(_sec_, _label_, _BEGIN_, _END_, _HDR_) \
218 _label_##_HDR_ = .; \
219 KEEP(*(.gnu.linkonce.##_sec_)) \
220 BOUNDED_SECTION_POST_LABEL(_sec_, _label_, _BEGIN_, _END_)
221
222#define HEADERED_SECTION_BY(_sec_, _label_) \
223 HEADERED_SECTION_PRE_LABEL(_sec_, _label_, __start, __stop)
224
225#define HEADERED_SECTION(_sec) HEADERED_SECTION_BY(_sec, _sec)
226
227#ifdef CONFIG_TRACE_BRANCH_PROFILING
228#define LIKELY_PROFILE() \
229 BOUNDED_SECTION_BY(_ftrace_annotated_branch, _annotated_branch_profile)
230#else
231#define LIKELY_PROFILE()
232#endif
233
234#ifdef CONFIG_PROFILE_ALL_BRANCHES
235#define BRANCH_PROFILE() \
236 BOUNDED_SECTION_BY(_ftrace_branch, _branch_profile)
237#else
238#define BRANCH_PROFILE()
239#endif
240
241#ifdef CONFIG_KPROBES
242#define KPROBE_BLACKLIST() \
243 . = ALIGN(8); \
244 BOUNDED_SECTION(_kprobe_blacklist)
245#else
246#define KPROBE_BLACKLIST()
247#endif
248
249#ifdef CONFIG_FUNCTION_ERROR_INJECTION
250#define ERROR_INJECT_WHITELIST() \
251 STRUCT_ALIGN(); \
252 BOUNDED_SECTION(_error_injection_whitelist)
253#else
254#define ERROR_INJECT_WHITELIST()
255#endif
256
257#ifdef CONFIG_EVENT_TRACING
258#define FTRACE_EVENTS() \
259 . = ALIGN(8); \
260 BOUNDED_SECTION(_ftrace_events) \
261 BOUNDED_SECTION_BY(_ftrace_eval_map, _ftrace_eval_maps)
262#else
263#define FTRACE_EVENTS()
264#endif
265
266#ifdef CONFIG_TRACING
267#define TRACE_PRINTKS() BOUNDED_SECTION_BY(__trace_printk_fmt, ___trace_bprintk_fmt)
268#define TRACEPOINT_STR() BOUNDED_SECTION_BY(__tracepoint_str, ___tracepoint_str)
269#else
270#define TRACE_PRINTKS()
271#define TRACEPOINT_STR()
272#endif
273
274#ifdef CONFIG_FTRACE_SYSCALLS
275#define TRACE_SYSCALLS() \
276 . = ALIGN(8); \
277 BOUNDED_SECTION_BY(__syscalls_metadata, _syscalls_metadata)
278#else
279#define TRACE_SYSCALLS()
280#endif
281
282#ifdef CONFIG_BPF_EVENTS
283#define BPF_RAW_TP() STRUCT_ALIGN(); \
284 BOUNDED_SECTION_BY(__bpf_raw_tp_map, __bpf_raw_tp)
285#else
286#define BPF_RAW_TP()
287#endif
288
289#ifdef CONFIG_SERIAL_EARLYCON
290#define EARLYCON_TABLE() \
291 . = ALIGN(8); \
292 BOUNDED_SECTION_POST_LABEL(__earlycon_table, __earlycon_table, , _end)
293#else
294#define EARLYCON_TABLE()
295#endif
296
297#ifdef CONFIG_SECURITY
298#define LSM_TABLE() \
299 . = ALIGN(8); \
300 BOUNDED_SECTION_PRE_LABEL(.lsm_info.init, _lsm_info, __start, __end)
301
302#define EARLY_LSM_TABLE() \
303 . = ALIGN(8); \
304 BOUNDED_SECTION_PRE_LABEL(.early_lsm_info.init, _early_lsm_info, __start, __end)
305#else
306#define LSM_TABLE()
307#define EARLY_LSM_TABLE()
308#endif
309
310#define ___OF_TABLE(cfg, name) _OF_TABLE_##cfg(name)
311#define __OF_TABLE(cfg, name) ___OF_TABLE(cfg, name)
312#define OF_TABLE(cfg, name) __OF_TABLE(IS_ENABLED(cfg), name)
313#define _OF_TABLE_0(name)
314#define _OF_TABLE_1(name) \
315 . = ALIGN(8); \
316 __##name##_of_table = .; \
317 KEEP(*(__##name##_of_table)) \
318 KEEP(*(__##name##_of_table_end))
319
320#define TIMER_OF_TABLES() OF_TABLE(CONFIG_TIMER_OF, timer)
321#define IRQCHIP_OF_MATCH_TABLE() OF_TABLE(CONFIG_IRQCHIP, irqchip)
322#define CLK_OF_TABLES() OF_TABLE(CONFIG_COMMON_CLK, clk)
323#define RESERVEDMEM_OF_TABLES() OF_TABLE(CONFIG_OF_RESERVED_MEM, reservedmem)
324#define CPU_METHOD_OF_TABLES() OF_TABLE(CONFIG_SMP, cpu_method)
325#define CPUIDLE_METHOD_OF_TABLES() OF_TABLE(CONFIG_CPU_IDLE, cpuidle_method)
326
327#ifdef CONFIG_ACPI
328#define ACPI_PROBE_TABLE(name) \
329 . = ALIGN(8); \
330 BOUNDED_SECTION_POST_LABEL(__##name##_acpi_probe_table, \
331 __##name##_acpi_probe_table,, _end)
332#else
333#define ACPI_PROBE_TABLE(name)
334#endif
335
336#ifdef CONFIG_THERMAL
337#define THERMAL_TABLE(name) \
338 . = ALIGN(8); \
339 BOUNDED_SECTION_POST_LABEL(__##name##_thermal_table, \
340 __##name##_thermal_table,, _end)
341#else
342#define THERMAL_TABLE(name)
343#endif
344
345#define KERNEL_DTB() \
346 STRUCT_ALIGN(); \
347 __dtb_start = .; \
348 KEEP(*(.dtb.init.rodata)) \
349 __dtb_end = .;
350
351/*
352 * .data section
353 */
354#define DATA_DATA \
355 *(.xiptext) \
356 *(DATA_MAIN) \
357 *(.data..decrypted) \
358 *(.ref.data) \
359 *(.data..shared_aligned) /* percpu related */ \
360 *(.data..unlikely) \
361 __start_once = .; \
362 *(.data..once) \
363 __end_once = .; \
364 *(.data..do_once) \
365 STRUCT_ALIGN(); \
366 *(__tracepoints) \
367 /* implement dynamic printk debug */ \
368 . = ALIGN(8); \
369 BOUNDED_SECTION_BY(__dyndbg_classes, ___dyndbg_classes) \
370 BOUNDED_SECTION_BY(__dyndbg, ___dyndbg) \
371 CODETAG_SECTIONS() \
372 LIKELY_PROFILE() \
373 BRANCH_PROFILE() \
374 TRACE_PRINTKS() \
375 BPF_RAW_TP() \
376 TRACEPOINT_STR() \
377 KUNIT_TABLE()
378
379/*
380 * Data section helpers
381 */
382#define NOSAVE_DATA \
383 . = ALIGN(PAGE_SIZE); \
384 __nosave_begin = .; \
385 *(.data..nosave) \
386 . = ALIGN(PAGE_SIZE); \
387 __nosave_end = .;
388
389#define CACHE_HOT_DATA(align) \
390 . = ALIGN(align); \
391 *(SORT_BY_ALIGNMENT(.data..hot.*)) \
392 . = ALIGN(align);
393
394#define PAGE_ALIGNED_DATA(page_align) \
395 . = ALIGN(page_align); \
396 *(.data..page_aligned) \
397 . = ALIGN(page_align);
398
399#define READ_MOSTLY_DATA(align) \
400 . = ALIGN(align); \
401 *(.data..read_mostly) \
402 . = ALIGN(align);
403
404#define CACHELINE_ALIGNED_DATA(align) \
405 . = ALIGN(align); \
406 *(.data..cacheline_aligned)
407
408#define INIT_TASK_DATA(align) \
409 . = ALIGN(align); \
410 __start_init_stack = .; \
411 init_thread_union = .; \
412 init_stack = .; \
413 KEEP(*(.data..init_thread_info)) \
414 . = __start_init_stack + THREAD_SIZE; \
415 __end_init_stack = .;
416
417#define JUMP_TABLE_DATA \
418 . = ALIGN(8); \
419 BOUNDED_SECTION_BY(__jump_table, ___jump_table)
420
421#ifdef CONFIG_HAVE_STATIC_CALL_INLINE
422#define STATIC_CALL_DATA \
423 . = ALIGN(8); \
424 BOUNDED_SECTION_BY(.static_call_sites, _static_call_sites) \
425 BOUNDED_SECTION_BY(.static_call_tramp_key, _static_call_tramp_key)
426#else
427#define STATIC_CALL_DATA
428#endif
429
430/*
431 * Allow architectures to handle ro_after_init data on their
432 * own by defining an empty RO_AFTER_INIT_DATA.
433 */
434#ifndef RO_AFTER_INIT_DATA
435#define RO_AFTER_INIT_DATA \
436 . = ALIGN(8); \
437 __start_ro_after_init = .; \
438 *(.data..ro_after_init) \
439 JUMP_TABLE_DATA \
440 STATIC_CALL_DATA \
441 __end_ro_after_init = .;
442#endif
443
444/*
445 * .kcfi_traps contains a list KCFI trap locations.
446 */
447#ifndef KCFI_TRAPS
448#ifdef CONFIG_ARCH_USES_CFI_TRAPS
449#define KCFI_TRAPS \
450 __kcfi_traps : AT(ADDR(__kcfi_traps) - LOAD_OFFSET) { \
451 BOUNDED_SECTION_BY(.kcfi_traps, ___kcfi_traps) \
452 }
453#else
454#define KCFI_TRAPS
455#endif
456#endif
457
458/*
459 * Read only Data
460 */
461#define RO_DATA(align) \
462 . = ALIGN((align)); \
463 .rodata : AT(ADDR(.rodata) - LOAD_OFFSET) { \
464 __start_rodata = .; \
465 *(.rodata) *(.rodata.*) *(.data.rel.ro*) \
466 SCHED_DATA \
467 RO_AFTER_INIT_DATA /* Read only after init */ \
468 . = ALIGN(8); \
469 BOUNDED_SECTION_BY(__tracepoints_ptrs, ___tracepoints_ptrs) \
470 *(__tracepoints_strings)/* Tracepoints: strings */ \
471 } \
472 \
473 .rodata1 : AT(ADDR(.rodata1) - LOAD_OFFSET) { \
474 *(.rodata1) \
475 } \
476 \
477 /* PCI quirks */ \
478 .pci_fixup : AT(ADDR(.pci_fixup) - LOAD_OFFSET) { \
479 BOUNDED_SECTION_PRE_LABEL(.pci_fixup_early, _pci_fixups_early, __start, __end) \
480 BOUNDED_SECTION_PRE_LABEL(.pci_fixup_header, _pci_fixups_header, __start, __end) \
481 BOUNDED_SECTION_PRE_LABEL(.pci_fixup_final, _pci_fixups_final, __start, __end) \
482 BOUNDED_SECTION_PRE_LABEL(.pci_fixup_enable, _pci_fixups_enable, __start, __end) \
483 BOUNDED_SECTION_PRE_LABEL(.pci_fixup_resume, _pci_fixups_resume, __start, __end) \
484 BOUNDED_SECTION_PRE_LABEL(.pci_fixup_suspend, _pci_fixups_suspend, __start, __end) \
485 BOUNDED_SECTION_PRE_LABEL(.pci_fixup_resume_early, _pci_fixups_resume_early, __start, __end) \
486 BOUNDED_SECTION_PRE_LABEL(.pci_fixup_suspend_late, _pci_fixups_suspend_late, __start, __end) \
487 } \
488 \
489 FW_LOADER_BUILT_IN_DATA \
490 TRACEDATA \
491 \
492 PRINTK_INDEX \
493 \
494 /* Kernel symbol table: Normal symbols */ \
495 __ksymtab : AT(ADDR(__ksymtab) - LOAD_OFFSET) { \
496 __start___ksymtab = .; \
497 KEEP(*(SORT(___ksymtab+*))) \
498 __stop___ksymtab = .; \
499 } \
500 \
501 /* Kernel symbol table: GPL-only symbols */ \
502 __ksymtab_gpl : AT(ADDR(__ksymtab_gpl) - LOAD_OFFSET) { \
503 __start___ksymtab_gpl = .; \
504 KEEP(*(SORT(___ksymtab_gpl+*))) \
505 __stop___ksymtab_gpl = .; \
506 } \
507 \
508 /* Kernel symbol table: Normal symbols */ \
509 __kcrctab : AT(ADDR(__kcrctab) - LOAD_OFFSET) { \
510 __start___kcrctab = .; \
511 KEEP(*(SORT(___kcrctab+*))) \
512 __stop___kcrctab = .; \
513 } \
514 \
515 /* Kernel symbol table: GPL-only symbols */ \
516 __kcrctab_gpl : AT(ADDR(__kcrctab_gpl) - LOAD_OFFSET) { \
517 __start___kcrctab_gpl = .; \
518 KEEP(*(SORT(___kcrctab_gpl+*))) \
519 __stop___kcrctab_gpl = .; \
520 } \
521 \
522 /* Kernel symbol table: strings */ \
523 __ksymtab_strings : AT(ADDR(__ksymtab_strings) - LOAD_OFFSET) { \
524 *(__ksymtab_strings) \
525 } \
526 \
527 /* __*init sections */ \
528 __init_rodata : AT(ADDR(__init_rodata) - LOAD_OFFSET) { \
529 *(.ref.rodata) \
530 } \
531 \
532 /* Built-in module parameters. */ \
533 __param : AT(ADDR(__param) - LOAD_OFFSET) { \
534 BOUNDED_SECTION_BY(__param, ___param) \
535 } \
536 \
537 /* Built-in module versions. */ \
538 __modver : AT(ADDR(__modver) - LOAD_OFFSET) { \
539 BOUNDED_SECTION_BY(__modver, ___modver) \
540 } \
541 \
542 KCFI_TRAPS \
543 \
544 RO_EXCEPTION_TABLE \
545 NOTES \
546 BTF \
547 \
548 . = ALIGN((align)); \
549 __end_rodata = .;
550
551
552/*
553 * Non-instrumentable text section
554 */
555#define NOINSTR_TEXT \
556 ALIGN_FUNCTION(); \
557 __noinstr_text_start = .; \
558 *(.noinstr.text) \
559 __cpuidle_text_start = .; \
560 *(.cpuidle.text) \
561 __cpuidle_text_end = .; \
562 __noinstr_text_end = .;
563
564#define TEXT_SPLIT \
565 __split_text_start = .; \
566 *(.text.split .text.split.[0-9a-zA-Z_]*) \
567 __split_text_end = .;
568
569#define TEXT_UNLIKELY \
570 __unlikely_text_start = .; \
571 *(.text.unlikely .text.unlikely.*) \
572 __unlikely_text_end = .;
573
574#define TEXT_HOT \
575 __hot_text_start = .; \
576 *(.text.hot .text.hot.*) \
577 __hot_text_end = .;
578
579/*
580 * .text section. Map to function alignment to avoid address changes
581 * during second ld run in second ld pass when generating System.map
582 *
583 * TEXT_MAIN here will match symbols with a fixed pattern (for example,
584 * .text.hot or .text.unlikely) if dead code elimination or
585 * function-section is enabled. Match these symbols first before
586 * TEXT_MAIN to ensure they are grouped together.
587 *
588 * Also placing .text.hot section at the beginning of a page, this
589 * would help the TLB performance.
590 */
591#define TEXT_TEXT \
592 ALIGN_FUNCTION(); \
593 *(.text.asan.* .text.tsan.*) \
594 *(.text.unknown .text.unknown.*) \
595 TEXT_SPLIT \
596 TEXT_UNLIKELY \
597 . = ALIGN(PAGE_SIZE); \
598 TEXT_HOT \
599 *(TEXT_MAIN .text.fixup) \
600 NOINSTR_TEXT \
601 *(.ref.text)
602
603/* sched.text is aling to function alignment to secure we have same
604 * address even at second ld pass when generating System.map */
605#define SCHED_TEXT \
606 ALIGN_FUNCTION(); \
607 __sched_text_start = .; \
608 *(.sched.text) \
609 __sched_text_end = .;
610
611/* spinlock.text is aling to function alignment to secure we have same
612 * address even at second ld pass when generating System.map */
613#define LOCK_TEXT \
614 ALIGN_FUNCTION(); \
615 __lock_text_start = .; \
616 *(.spinlock.text) \
617 __lock_text_end = .;
618
619#define KPROBES_TEXT \
620 ALIGN_FUNCTION(); \
621 __kprobes_text_start = .; \
622 *(.kprobes.text) \
623 __kprobes_text_end = .;
624
625#define ENTRY_TEXT \
626 ALIGN_FUNCTION(); \
627 __entry_text_start = .; \
628 *(.entry.text) \
629 __entry_text_end = .;
630
631#define IRQENTRY_TEXT \
632 ALIGN_FUNCTION(); \
633 __irqentry_text_start = .; \
634 *(.irqentry.text) \
635 __irqentry_text_end = .;
636
637#define SOFTIRQENTRY_TEXT \
638 ALIGN_FUNCTION(); \
639 __softirqentry_text_start = .; \
640 *(.softirqentry.text) \
641 __softirqentry_text_end = .;
642
643#define STATIC_CALL_TEXT \
644 ALIGN_FUNCTION(); \
645 __static_call_text_start = .; \
646 *(.static_call.text) \
647 __static_call_text_end = .;
648
649/* Section used for early init (in .S files) */
650#define HEAD_TEXT KEEP(*(.head.text))
651
652#define HEAD_TEXT_SECTION \
653 .head.text : AT(ADDR(.head.text) - LOAD_OFFSET) { \
654 HEAD_TEXT \
655 }
656
657/*
658 * Exception table
659 */
660#define EXCEPTION_TABLE(align) \
661 . = ALIGN(align); \
662 __ex_table : AT(ADDR(__ex_table) - LOAD_OFFSET) { \
663 BOUNDED_SECTION_BY(__ex_table, ___ex_table) \
664 }
665
666/*
667 * .BTF
668 */
669#ifdef CONFIG_DEBUG_INFO_BTF
670#define BTF \
671 . = ALIGN(PAGE_SIZE); \
672 .BTF : AT(ADDR(.BTF) - LOAD_OFFSET) { \
673 BOUNDED_SECTION_BY(.BTF, _BTF) \
674 } \
675 . = ALIGN(PAGE_SIZE); \
676 .BTF_ids : AT(ADDR(.BTF_ids) - LOAD_OFFSET) { \
677 *(.BTF_ids) \
678 }
679#else
680#define BTF
681#endif
682
683/*
684 * Init task
685 */
686#define INIT_TASK_DATA_SECTION(align) \
687 . = ALIGN(align); \
688 .data..init_task : AT(ADDR(.data..init_task) - LOAD_OFFSET) { \
689 INIT_TASK_DATA(align) \
690 }
691
692#ifdef CONFIG_CONSTRUCTORS
693#define KERNEL_CTORS() . = ALIGN(8); \
694 __ctors_start = .; \
695 KEEP(*(SORT(.ctors.*))) \
696 KEEP(*(.ctors)) \
697 KEEP(*(SORT(.init_array.*))) \
698 KEEP(*(.init_array)) \
699 __ctors_end = .;
700#else
701#define KERNEL_CTORS()
702#endif
703
704/* init and exit section handling */
705#define INIT_DATA \
706 KEEP(*(SORT(___kentry+*))) \
707 *(.init.data .init.data.*) \
708 KERNEL_CTORS() \
709 MCOUNT_REC() \
710 *(.init.rodata .init.rodata.*) \
711 FTRACE_EVENTS() \
712 TRACE_SYSCALLS() \
713 KPROBE_BLACKLIST() \
714 ERROR_INJECT_WHITELIST() \
715 CLK_OF_TABLES() \
716 RESERVEDMEM_OF_TABLES() \
717 TIMER_OF_TABLES() \
718 CPU_METHOD_OF_TABLES() \
719 CPUIDLE_METHOD_OF_TABLES() \
720 KERNEL_DTB() \
721 IRQCHIP_OF_MATCH_TABLE() \
722 ACPI_PROBE_TABLE(irqchip) \
723 ACPI_PROBE_TABLE(timer) \
724 THERMAL_TABLE(governor) \
725 EARLYCON_TABLE() \
726 LSM_TABLE() \
727 EARLY_LSM_TABLE() \
728 KUNIT_INIT_TABLE()
729
730#define INIT_TEXT \
731 *(.init.text .init.text.*) \
732 *(.text.startup)
733
734#define EXIT_DATA \
735 *(.exit.data .exit.data.*) \
736 *(.fini_array .fini_array.*) \
737 *(.dtors .dtors.*) \
738
739#define EXIT_TEXT \
740 *(.exit.text) \
741 *(.text.exit) \
742
743#define EXIT_CALL \
744 *(.exitcall.exit)
745
746/*
747 * bss (Block Started by Symbol) - uninitialized data
748 * zeroed during startup
749 */
750#define SBSS(sbss_align) \
751 . = ALIGN(sbss_align); \
752 .sbss : AT(ADDR(.sbss) - LOAD_OFFSET) { \
753 *(.dynsbss) \
754 *(SBSS_MAIN) \
755 *(.scommon) \
756 }
757
758/*
759 * Allow archectures to redefine BSS_FIRST_SECTIONS to add extra
760 * sections to the front of bss.
761 */
762#ifndef BSS_FIRST_SECTIONS
763#define BSS_FIRST_SECTIONS
764#endif
765
766#define BSS(bss_align) \
767 . = ALIGN(bss_align); \
768 .bss : AT(ADDR(.bss) - LOAD_OFFSET) { \
769 BSS_FIRST_SECTIONS \
770 . = ALIGN(PAGE_SIZE); \
771 *(.bss..page_aligned) \
772 . = ALIGN(PAGE_SIZE); \
773 *(.dynbss) \
774 *(BSS_MAIN) \
775 *(COMMON) \
776 }
777
778/*
779 * DWARF debug sections.
780 * Symbols in the DWARF debugging sections are relative to
781 * the beginning of the section so we begin them at 0.
782 */
783#define DWARF_DEBUG \
784 /* DWARF 1 */ \
785 .debug 0 : { *(.debug) } \
786 .line 0 : { *(.line) } \
787 /* GNU DWARF 1 extensions */ \
788 .debug_srcinfo 0 : { *(.debug_srcinfo) } \
789 .debug_sfnames 0 : { *(.debug_sfnames) } \
790 /* DWARF 1.1 and DWARF 2 */ \
791 .debug_aranges 0 : { *(.debug_aranges) } \
792 .debug_pubnames 0 : { *(.debug_pubnames) } \
793 /* DWARF 2 */ \
794 .debug_info 0 : { *(.debug_info \
795 .gnu.linkonce.wi.*) } \
796 .debug_abbrev 0 : { *(.debug_abbrev) } \
797 .debug_line 0 : { *(.debug_line) } \
798 .debug_frame 0 : { *(.debug_frame) } \
799 .debug_str 0 : { *(.debug_str) } \
800 .debug_loc 0 : { *(.debug_loc) } \
801 .debug_macinfo 0 : { *(.debug_macinfo) } \
802 .debug_pubtypes 0 : { *(.debug_pubtypes) } \
803 /* DWARF 3 */ \
804 .debug_ranges 0 : { *(.debug_ranges) } \
805 /* SGI/MIPS DWARF 2 extensions */ \
806 .debug_weaknames 0 : { *(.debug_weaknames) } \
807 .debug_funcnames 0 : { *(.debug_funcnames) } \
808 .debug_typenames 0 : { *(.debug_typenames) } \
809 .debug_varnames 0 : { *(.debug_varnames) } \
810 /* GNU DWARF 2 extensions */ \
811 .debug_gnu_pubnames 0 : { *(.debug_gnu_pubnames) } \
812 .debug_gnu_pubtypes 0 : { *(.debug_gnu_pubtypes) } \
813 /* DWARF 4 */ \
814 .debug_types 0 : { *(.debug_types) } \
815 /* DWARF 5 */ \
816 .debug_addr 0 : { *(.debug_addr) } \
817 .debug_line_str 0 : { *(.debug_line_str) } \
818 .debug_loclists 0 : { *(.debug_loclists) } \
819 .debug_macro 0 : { *(.debug_macro) } \
820 .debug_names 0 : { *(.debug_names) } \
821 .debug_rnglists 0 : { *(.debug_rnglists) } \
822 .debug_str_offsets 0 : { *(.debug_str_offsets) }
823
824/* Stabs debugging sections. */
825#define STABS_DEBUG \
826 .stab 0 : { *(.stab) } \
827 .stabstr 0 : { *(.stabstr) } \
828 .stab.excl 0 : { *(.stab.excl) } \
829 .stab.exclstr 0 : { *(.stab.exclstr) } \
830 .stab.index 0 : { *(.stab.index) } \
831 .stab.indexstr 0 : { *(.stab.indexstr) }
832
833/* Required sections not related to debugging. */
834#define ELF_DETAILS \
835 .comment 0 : { *(.comment) } \
836 .symtab 0 : { *(.symtab) } \
837 .strtab 0 : { *(.strtab) } \
838 .shstrtab 0 : { *(.shstrtab) }
839
840#define MODINFO \
841 .modinfo : { *(.modinfo) . = ALIGN(8); }
842
843#ifdef CONFIG_GENERIC_BUG
844#define BUG_TABLE \
845 . = ALIGN(8); \
846 __bug_table : AT(ADDR(__bug_table) - LOAD_OFFSET) { \
847 BOUNDED_SECTION_BY(__bug_table, ___bug_table) \
848 }
849#else
850#define BUG_TABLE
851#endif
852
853#ifdef CONFIG_UNWINDER_ORC
854#define ORC_UNWIND_TABLE \
855 .orc_header : AT(ADDR(.orc_header) - LOAD_OFFSET) { \
856 BOUNDED_SECTION_BY(.orc_header, _orc_header) \
857 } \
858 . = ALIGN(4); \
859 .orc_unwind_ip : AT(ADDR(.orc_unwind_ip) - LOAD_OFFSET) { \
860 BOUNDED_SECTION_BY(.orc_unwind_ip, _orc_unwind_ip) \
861 } \
862 . = ALIGN(2); \
863 .orc_unwind : AT(ADDR(.orc_unwind) - LOAD_OFFSET) { \
864 BOUNDED_SECTION_BY(.orc_unwind, _orc_unwind) \
865 } \
866 text_size = _etext - _stext; \
867 . = ALIGN(4); \
868 .orc_lookup : AT(ADDR(.orc_lookup) - LOAD_OFFSET) { \
869 orc_lookup = .; \
870 . += (((text_size + LOOKUP_BLOCK_SIZE - 1) / \
871 LOOKUP_BLOCK_SIZE) + 1) * 4; \
872 orc_lookup_end = .; \
873 }
874#else
875#define ORC_UNWIND_TABLE
876#endif
877
878/* Built-in firmware blobs */
879#ifdef CONFIG_FW_LOADER
880#define FW_LOADER_BUILT_IN_DATA \
881 .builtin_fw : AT(ADDR(.builtin_fw) - LOAD_OFFSET) ALIGN(8) { \
882 BOUNDED_SECTION_PRE_LABEL(.builtin_fw, _builtin_fw, __start, __end) \
883 }
884#else
885#define FW_LOADER_BUILT_IN_DATA
886#endif
887
888#ifdef CONFIG_PM_TRACE
889#define TRACEDATA \
890 . = ALIGN(4); \
891 .tracedata : AT(ADDR(.tracedata) - LOAD_OFFSET) { \
892 BOUNDED_SECTION_POST_LABEL(.tracedata, __tracedata, _start, _end) \
893 }
894#else
895#define TRACEDATA
896#endif
897
898#ifdef CONFIG_PRINTK_INDEX
899#define PRINTK_INDEX \
900 .printk_index : AT(ADDR(.printk_index) - LOAD_OFFSET) { \
901 BOUNDED_SECTION_BY(.printk_index, _printk_index) \
902 }
903#else
904#define PRINTK_INDEX
905#endif
906
907/*
908 * Discard .note.GNU-stack, which is emitted as PROGBITS by the compiler.
909 * Otherwise, the type of .notes section would become PROGBITS instead of NOTES.
910 *
911 * Also, discard .note.gnu.property, otherwise it forces the notes section to
912 * be 8-byte aligned which causes alignment mismatches with the kernel's custom
913 * 4-byte aligned notes.
914 */
915#define NOTES \
916 /DISCARD/ : { \
917 *(.note.GNU-stack) \
918 *(.note.gnu.property) \
919 } \
920 .notes : AT(ADDR(.notes) - LOAD_OFFSET) { \
921 BOUNDED_SECTION_BY(.note.*, _notes) \
922 } NOTES_HEADERS \
923 NOTES_HEADERS_RESTORE
924
925#define INIT_SETUP(initsetup_align) \
926 . = ALIGN(initsetup_align); \
927 BOUNDED_SECTION_POST_LABEL(.init.setup, __setup, _start, _end)
928
929#define INIT_CALLS_LEVEL(level) \
930 __initcall##level##_start = .; \
931 KEEP(*(.initcall##level##.init)) \
932 KEEP(*(.initcall##level##s.init)) \
933
934#define INIT_CALLS \
935 __initcall_start = .; \
936 KEEP(*(.initcallearly.init)) \
937 INIT_CALLS_LEVEL(0) \
938 INIT_CALLS_LEVEL(1) \
939 INIT_CALLS_LEVEL(2) \
940 INIT_CALLS_LEVEL(3) \
941 INIT_CALLS_LEVEL(4) \
942 INIT_CALLS_LEVEL(5) \
943 INIT_CALLS_LEVEL(rootfs) \
944 INIT_CALLS_LEVEL(6) \
945 INIT_CALLS_LEVEL(7) \
946 __initcall_end = .;
947
948#define CON_INITCALL \
949 BOUNDED_SECTION_POST_LABEL(.con_initcall.init, __con_initcall, _start, _end)
950
951#define NAMED_SECTION(name) \
952 . = ALIGN(8); \
953 name : AT(ADDR(name) - LOAD_OFFSET) \
954 { BOUNDED_SECTION_PRE_LABEL(name, name, __start_, __stop_) }
955
956#define RUNTIME_CONST(t,x) NAMED_SECTION(runtime_##t##_##x)
957
958#define RUNTIME_CONST_VARIABLES \
959 RUNTIME_CONST(shift, d_hash_shift) \
960 RUNTIME_CONST(ptr, dentry_hashtable)
961
962/* Alignment must be consistent with (kunit_suite *) in include/kunit/test.h */
963#define KUNIT_TABLE() \
964 . = ALIGN(8); \
965 BOUNDED_SECTION_POST_LABEL(.kunit_test_suites, __kunit_suites, _start, _end)
966
967/* Alignment must be consistent with (kunit_suite *) in include/kunit/test.h */
968#define KUNIT_INIT_TABLE() \
969 . = ALIGN(8); \
970 BOUNDED_SECTION_POST_LABEL(.kunit_init_test_suites, \
971 __kunit_init_suites, _start, _end)
972
973#ifdef CONFIG_BLK_DEV_INITRD
974#define INIT_RAM_FS \
975 . = ALIGN(4); \
976 __initramfs_start = .; \
977 KEEP(*(.init.ramfs)) \
978 . = ALIGN(8); \
979 KEEP(*(.init.ramfs.info))
980#else
981#define INIT_RAM_FS
982#endif
983
984/*
985 * Memory encryption operates on a page basis. Since we need to clear
986 * the memory encryption mask for this section, it needs to be aligned
987 * on a page boundary and be a page-size multiple in length.
988 *
989 * Note: We use a separate section so that only this section gets
990 * decrypted to avoid exposing more than we wish.
991 */
992#ifdef CONFIG_AMD_MEM_ENCRYPT
993#define PERCPU_DECRYPTED_SECTION \
994 . = ALIGN(PAGE_SIZE); \
995 *(.data..percpu..decrypted) \
996 . = ALIGN(PAGE_SIZE);
997#else
998#define PERCPU_DECRYPTED_SECTION
999#endif
1000
1001
1002/*
1003 * Default discarded sections.
1004 *
1005 * Some archs want to discard exit text/data at runtime rather than
1006 * link time due to cross-section references such as alt instructions,
1007 * bug table, eh_frame, etc. DISCARDS must be the last of output
1008 * section definitions so that such archs put those in earlier section
1009 * definitions.
1010 */
1011#ifdef RUNTIME_DISCARD_EXIT
1012#define EXIT_DISCARDS
1013#else
1014#define EXIT_DISCARDS \
1015 EXIT_TEXT \
1016 EXIT_DATA
1017#endif
1018
1019/*
1020 * Clang's -fprofile-arcs, -fsanitize=kernel-address, and
1021 * -fsanitize=thread produce unwanted sections (.eh_frame
1022 * and .init_array.*), but CONFIG_CONSTRUCTORS wants to
1023 * keep any .init_array.* sections.
1024 * https://llvm.org/pr46478
1025 */
1026#ifdef CONFIG_UNWIND_TABLES
1027#define DISCARD_EH_FRAME
1028#else
1029#define DISCARD_EH_FRAME *(.eh_frame)
1030#endif
1031#if defined(CONFIG_GCOV_KERNEL) || defined(CONFIG_KASAN_GENERIC) || defined(CONFIG_KCSAN)
1032# ifdef CONFIG_CONSTRUCTORS
1033# define SANITIZER_DISCARDS \
1034 DISCARD_EH_FRAME
1035# else
1036# define SANITIZER_DISCARDS \
1037 *(.init_array) *(.init_array.*) \
1038 DISCARD_EH_FRAME
1039# endif
1040#else
1041# define SANITIZER_DISCARDS
1042#endif
1043
1044#define COMMON_DISCARDS \
1045 SANITIZER_DISCARDS \
1046 PATCHABLE_DISCARDS \
1047 *(.discard) \
1048 *(.discard.*) \
1049 *(.export_symbol) \
1050 *(.no_trim_symbol) \
1051 /* ld.bfd warns about .gnu.version* even when not emitted */ \
1052 *(.gnu.version*) \
1053
1054#define DISCARDS \
1055 /DISCARD/ : { \
1056 EXIT_DISCARDS \
1057 EXIT_CALL \
1058 COMMON_DISCARDS \
1059 }
1060
1061/**
1062 * PERCPU_INPUT - the percpu input sections
1063 * @cacheline: cacheline size
1064 *
1065 * The core percpu section names and core symbols which do not rely
1066 * directly upon load addresses.
1067 *
1068 * @cacheline is used to align subsections to avoid false cacheline
1069 * sharing between subsections for different purposes.
1070 */
1071#define PERCPU_INPUT(cacheline) \
1072 __per_cpu_start = .; \
1073 . = ALIGN(PAGE_SIZE); \
1074 *(.data..percpu..page_aligned) \
1075 . = ALIGN(cacheline); \
1076 __per_cpu_hot_start = .; \
1077 *(SORT_BY_ALIGNMENT(.data..percpu..hot.*)) \
1078 __per_cpu_hot_end = .; \
1079 . = ALIGN(cacheline); \
1080 *(.data..percpu..read_mostly) \
1081 . = ALIGN(cacheline); \
1082 *(.data..percpu) \
1083 *(.data..percpu..shared_aligned) \
1084 PERCPU_DECRYPTED_SECTION \
1085 __per_cpu_end = .;
1086
1087/**
1088 * PERCPU_SECTION - define output section for percpu area
1089 * @cacheline: cacheline size
1090 *
1091 * Macro which expands to output section for percpu area.
1092 *
1093 * @cacheline is used to align subsections to avoid false cacheline
1094 * sharing between subsections for different purposes.
1095 */
1096#define PERCPU_SECTION(cacheline) \
1097 . = ALIGN(PAGE_SIZE); \
1098 .data..percpu : AT(ADDR(.data..percpu) - LOAD_OFFSET) { \
1099 PERCPU_INPUT(cacheline) \
1100 }
1101
1102
1103/*
1104 * Definition of the high level *_SECTION macros
1105 * They will fit only a subset of the architectures
1106 */
1107
1108
1109/*
1110 * Writeable data.
1111 * All sections are combined in a single .data section.
1112 * The sections following CONSTRUCTORS are arranged so their
1113 * typical alignment matches.
1114 * A cacheline is typical/always less than a PAGE_SIZE so
1115 * the sections that has this restriction (or similar)
1116 * is located before the ones requiring PAGE_SIZE alignment.
1117 * NOSAVE_DATA starts and ends with a PAGE_SIZE alignment which
1118 * matches the requirement of PAGE_ALIGNED_DATA.
1119 *
1120 * use 0 as page_align if page_aligned data is not used */
1121#define RW_DATA(cacheline, pagealigned, inittask) \
1122 . = ALIGN(PAGE_SIZE); \
1123 .data : AT(ADDR(.data) - LOAD_OFFSET) { \
1124 INIT_TASK_DATA(inittask) \
1125 NOSAVE_DATA \
1126 PAGE_ALIGNED_DATA(pagealigned) \
1127 CACHE_HOT_DATA(cacheline) \
1128 CACHELINE_ALIGNED_DATA(cacheline) \
1129 READ_MOSTLY_DATA(cacheline) \
1130 DATA_DATA \
1131 CONSTRUCTORS \
1132 } \
1133 BUG_TABLE \
1134
1135#define INIT_TEXT_SECTION(inittext_align) \
1136 . = ALIGN(inittext_align); \
1137 .init.text : AT(ADDR(.init.text) - LOAD_OFFSET) { \
1138 _sinittext = .; \
1139 INIT_TEXT \
1140 _einittext = .; \
1141 }
1142
1143#define INIT_DATA_SECTION(initsetup_align) \
1144 .init.data : AT(ADDR(.init.data) - LOAD_OFFSET) { \
1145 INIT_DATA \
1146 INIT_SETUP(initsetup_align) \
1147 INIT_CALLS \
1148 CON_INITCALL \
1149 INIT_RAM_FS \
1150 }
1151
1152#define BSS_SECTION(sbss_align, bss_align, stop_align) \
1153 . = ALIGN(sbss_align); \
1154 __bss_start = .; \
1155 SBSS(sbss_align) \
1156 BSS(bss_align) \
1157 . = ALIGN(stop_align); \
1158 __bss_stop = .;